home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD003b.dsk / PLANET.OF.THE.ROBOTS.bas < prev    next >
BASIC Source File  |  2003-06-12  |  31KB  |  662 lines
  1. 2  REM  PLANET.OF.THE.ROBOTS
  2. 3  REM  BY DANIEL TOBIAS   11/81
  3. 4  REM  AN ADVENTURE-STYLE GAME
  4. 7 NA$ = "PLANET.OF.THE.ROBOTS"
  5. 10 D$ =  CHR$(4)
  6. 15  DIM LV%(100,8),LD$(100,1),R%(100),ID$(50),IL%(50),PR(50),IW(50),L%(100)
  7. 17  DIM WD$(100),W%(100,1),FW%(1)
  8. 20  GOSUB 18000: GOSUB 19000
  9. 50 SP = 128: SPEED= SP
  10. 60  HOME : PRINT 
  11. 100  REM  START
  12. 108 XX = 1
  13. 110  IF XX = 1  THEN  GOSUB 1000
  14. 120  GOSUB 500
  15. 125 XX = XX +1: IF XX >5  THEN XX = 1
  16. 130  IF FW%(0) = 0  THEN  PRINT "WHAT?": GOTO 110
  17. 140  ON FW%(0) GOSUB 2000,3000,4000,5000,5500,6000,7000,8000,9000,9500
  18. 142  IF FW%(0) >10  THEN  ON FW%(0) -10 GOSUB 13000,13500,14500,15000,15500,16000,16500,10000
  19. 145  IF FW%(0) = 99  THEN  PRINT "QUIT AFTER ";T;" TURNS.": SPEED= 255: END 
  20. 150 T = T +1
  21. 160  GOTO 110
  22. 500  REM  HANDLE INPUT
  23. 502  POKE  -16368,0
  24. 505 FW%(0) = 0:FW%(1) = 0
  25. 507  PRINT 
  26. 510  INPUT "-->";I$
  27. 515  IF I$ = ""  THEN 510
  28. 520 WD$ = "":A = 1
  29. 530  IF  MID$ (I$,A,1) = " "  THEN 600
  30. 540 WD$ = WD$ + MID$ (I$,A,1)
  31. 550 A = A +1: IF A < =  LEN(I$)  THEN 530
  32. 600  REM  FOUND WORD
  33. 610  FOR B = 1 TO NW: IF WD$(B) = WD$  THEN  GOSUB 650
  34. 620  NEXT B:WD$ = "":A = A +1
  35. 630  IF A > LEN(I$)  THEN  RETURN 
  36. 640  GOTO 530
  37. 650  FOR C = 0 TO 1
  38. 660  IF W%(B,C) > = 0  THEN FW%(C) = W%(B,C)
  39. 670  NEXT C
  40. 680  RETURN 
  41. 1000  REM  PRINT DESC
  42. 1002  IF LD$(L,0) = "S"  THEN  GOSUB 12000
  43. 1005  PRINT 
  44. 1010  PRINT LD$(L,L%(L))
  45. 1011  IF L = 28  AND J = 0  THEN  PRINT "THERE IS A DOOR WITH BARS."
  46. 1012  IF L = 28  AND J < >0  THEN  PRINT "THE BARS ARE BROKEN LEAVING A PATH OUT."
  47. 1014  PRINT 
  48. 1015 L%(L) = 1
  49. 1020  PRINT "OPEN PATHWAYS: ";: FOR A = 1 TO 8: IF LV%(L,A) < >0  THEN  PRINT DN$(A);
  50. 1025  NEXT A
  51. 1030  PRINT 
  52. 1040  PRINT "VISIBLE OBJECTS:"
  53. 1045 X = 0
  54. 1050  FOR A = 1 TO NI
  55. 1060  IF IL%(A) = L  THEN  PRINT " "ID$(A);:X = 1: IF PR(A) >0  AND R%(L) = 1  THEN  PRINT " (PRICE: $"PR(A)")";
  56. 1065  IF IL%(A) = L  THEN  PRINT 
  57. 1070  NEXT A
  58. 1080  IF X = 0  THEN  PRINT "THERE ARE NONE."
  59. 1085  IF R%(L) < >0  THEN  PRINT 
  60. 1090  IF R%(L) = 1  THEN  PRINT "CLERK ROBOT HERE."
  61. 1100  IF R%(L) >20  AND R%(L) <29  THEN  PRINT "GUARD ROBOT HERE."
  62. 1110  IF R%(L) = 3  THEN  PRINT "BERSERK ROBOT HERE!"
  63. 1120  IF T -E > = 100  THEN  PRINT : PRINT "YOU ARE GETTING HUNGRY!"
  64. 1490  RETURN 
  65. 2000  REM  MOVE
  66. 2005  IF FW%(1) <101  OR FW%(1) >108  THEN  PRINT "GO WHERE?": RETURN 
  67. 2010 X = LV%(L,FW%(1) -100)
  68. 2020  IF X <0  OR X >NL  THEN  PRINT "NOT DEFINED YET.": RETURN 
  69. 2025  IF L = 28  AND I$ = "BREAK OUT"  THEN 15000
  70. 2030  IF X = 0  THEN  PRINT "YOU CAN'T GO THAT WAY.": RETURN 
  71. 2035  IF R%(L) = 3  THEN  PRINT "ROBOT: TRYING TO ESCAPE, HUH?  IT WON'T  WORK!  ZAP!  YOU'RE DEAD!": PRINT : PRINT "STOP AFTER "T" TURNS.": SPEED= 255: END 
  72. 2040  IF X = 6  AND IL%(7) < >0  THEN  PRINT "ROBOT: I'M SORRY, BUT THE DRESS CODE     REQUIRES THAT YOU WEAR A TIE.": RETURN 
  73. 2042  IF L = 6  AND R < >0  THEN  PRINT "ROBOT: I'M SORRY. YOU ARE A BAD CREDIT   RISK. YOU CAN'T ENTER.": RETURN 
  74. 2045  IF R%(L) = 20 +FW%(1) -100  AND IL%(12) = 0  THEN  PRINT "ROBOT: I.D. ACCEPTED.  YOU CAN PASS.     GOOD DAY, MR. SMITH.": GOTO 2060
  75. 2050  IF R%(L) = 20 +FW%(1) -100  THEN  PRINT "ROBOT: I'M SORRY, BUT YOU CANNOT GO THAT WAY WITHOUT AN I.D. CARD.": RETURN 
  76. 2060  REM 
  77. 2065  IF L = 39  AND X = 39  AND  RND(1) <.35  THEN PL = 1 -PL:X = 35: IF PL = 0  THEN X = 40
  78. 2070  IF X = 17  THEN  PRINT "ROBOT: SORRY, THIS INFORMATION BOOTH IS  OUT OF ORDER.": RETURN 
  79. 2080  IF LD$(X,0) = "S"  THEN  GOSUB 12000: RETURN 
  80. 2090  IF L = 36  AND X = 37  THEN  INPUT "ENTER COMBINATION: ";A$: IF  VAL(A$) < >CM%  THEN  PRINT "SORRY. WRONG!": RETURN 
  81. 2100  IF X = 38  THEN 14000
  82. 2200 L = X:XX = 1: RETURN 
  83. 3000  REM  PICK UP
  84. 3005  IF FW%(1) = 0  OR FW%(1) >NI  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  85. 3006  IF IL%(FW%(1)) = 0  THEN  PRINT "YOU ARE ALREADY CARRYING IT!": RETURN 
  86. 3007  IF IL%(FW%(1)) < >L  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  87. 3009  IF PR(FW%(1)) >0  AND R%(L) = 1  THEN  PRINT "ROBOT: YOU CAN'T TAKE THAT WITHOUT       PAYING FOR IT!  PLEASE BUY IT IF YOU    WANT IT.": RETURN 
  88. 3010  IF WT +IW(FW%(1)) >150  AND IW(FW%(1)) < = 150  THEN  PRINT "TOO HEAVY. YOU MUST DROP SOMETHING      FIRST BEFORE YOU PICK IT UP.": RETURN 
  89. 3020  IF IW(FW%(1)) >150  THEN  PRINT "TOO HEAVY FOR YOU TO LIFT.": RETURN 
  90. 3030  IF IW(FW%(1)) <0  THEN  PRINT "IT IS SECURELY FASTENED.": RETURN 
  91. 3040 IL%(FW%(1)) = 0:WT = WT +IW(FW%(1))
  92. 3045  PRINT "OK."
  93. 3050  IF FW%(1) = 10  THEN M =  ABS(M)
  94. 3060  RETURN 
  95. 4000  REM  DROP
  96. 4010  IF FW%(1) <1  OR FW%(1) >NI  THEN  PRINT "YOU ARE NOT CARRYING ONE.": RETURN 
  97. 4020  IF IL%(FW%(1)) < >0  THEN  PRINT "YOU ARE NOT CARRYING ONE.": RETURN 
  98. 4030 IL%(FW%(1)) = L:WT = WT -IW(FW%(1))
  99. 4040  PRINT "OK."
  100. 4042  IF L = 39  THEN  PRINT "IT SLIDES INTO A CREVICE IN THE RUINS   AND IS LOST.":IL%(FW%(1)) =  -1
  101. 4045  IF FW%(1) = 10  THEN M =  - ABS(M)
  102. 4050  RETURN 
  103. 5000  REM  LOOK
  104. 5010 XX = 1
  105. 5015 L%(L) = 0
  106. 5020  RETURN 
  107. 5500  REM  INV
  108. 5505 X = 0
  109. 5510  PRINT "YOU ARE CARRYING: "
  110. 5520  FOR A = 1 TO NI
  111. 5525  IF A = 10  THEN 5540
  112. 5530  IF IL%(A) = 0  THEN  PRINT " "ID$(A):X = 1
  113. 5540  NEXT A
  114. 5545  IF M >0  THEN  PRINT " $"M" IN CASH.":X = 1
  115. 5550  IF X = 0  THEN  PRINT "NOTHING."
  116. 5560  RETURN 
  117. 6000  REM  SAVE GAME
  118. 6005  SPEED= 255
  119. 6010  INPUT "GAME #";A
  120. 6015  IF A <0  THEN 6010
  121. 6020  PRINT D$"OPEN GAME."NA$",L500"
  122. 6030  PRINT D$"WRITE GAME."NA$",R"A
  123. 6040  PRINT L: FOR B = 1 TO NI: PRINT IL%(B): NEXT B: PRINT WT: PRINT T
  124. 6050  FOR B = 1 TO NL: PRINT R%(B): NEXT B: PRINT M: PRINT E
  125. 6060  FOR B = 1 TO NI: PRINT PR(B): NEXT B
  126. 6070  PRINT CM%: PRINT R: PRINT J
  127. 6080  PRINT PW: PRINT RM
  128. 6090  PRINT D$"CLOSE"
  129. 6100  SPEED= 128: RETURN 
  130. 6500  REM  LOAD GAME
  131. 6510  ONERR  GOTO 6900
  132. 6520  INPUT "GAME #";A
  133. 6525  IF A <0  THEN 6520
  134. 6530  PRINT D$"OPEN GAME."NA$",L500"
  135. 6540  PRINT D$"READ GAME."NA$",R"A
  136. 6550  INPUT L: FOR B = 1 TO NI: INPUT IL%(B): NEXT B: INPUT WT: INPUT T
  137. 6560  FOR B = 1 TO NL: INPUT R%(B): NEXT B: INPUT M: INPUT E
  138. 6565  FOR B = 1 TO NI: INPUT PR(B): NEXT B
  139. 6570  INPUT CM%: INPUT R: INPUT J
  140. 6575  IF J  THEN LV%(28,8) = 27
  141. 6580  INPUT PW: INPUT RM
  142. 6590  PRINT D$"CLOSE"
  143. 6595  POKE 216,0
  144. 6600  RETURN 
  145. 6900  REM  ONERR
  146. 6905  POKE 216,0
  147. 6910  PRINT D$"CLOSE"
  148. 6920  PRINT "GAME NOT FOUND."
  149. 6930  RUN 
  150. 7000  REM  WEIGH
  151. 7010  IF IL%(2) < >L  AND IL%(2) < >0  THEN  PRINT "THERE IS NO SCALE.": RETURN 
  152. 7020  IF FW%(1) = 2  THEN  PRINT "YOU CAN'T WEIGH IT ON ITSELF!": RETURN 
  153. 7030  IF FW%(1) <1  OR FW%(1) >NI  THEN  PRINT "THERE IS NO SUCH ITEM HERE.": RETURN 
  154. 7040  IF IL%(FW%(1)) < >L  AND IL%(FW%(1)) < >0  THEN  PRINT "THERE IS NO SUCH ITEM HERE.": RETURN 
  155. 7050  PRINT "IT WEIGHS ";IW(FW%(1));" POUNDS."
  156. 7060  RETURN 
  157. 8000  REM  READ
  158. 8005  IF FW%(1) = 200  THEN  PRINT "THE BARS LOOK RUSTY AND WEAK.": RETURN 
  159. 8010  IF FW%(1) <1  OR FW%(1) >NI  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  160. 8020  IF IL%(FW%(1)) < >L  AND IL%(FW%(1)) < >0  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  161. 8030  IF FW%(1) = 5  THEN  PRINT "THE SIGN SAYS: INSERT $2.50": RETURN 
  162. 8050  IF FW%(1) = 10  THEN  PRINT "THEY ARE MOSTLY DOLLAR COINS, BUT THERE ARE SOME $2.50 PIECES.": RETURN 
  163. 8060  IF FW%(1) = 4  THEN  PRINT "IT IS HOOKED TO A MODEM.": RETURN 
  164. 8070  IF FW%(1) = 8  THEN  PRINT "IT IS THE ADVENTURES OF SUPERROBOT.": RETURN 
  165. 8080  IF FW%(1) = 12  THEN  PRINT "IT BELONGS TO SECRET AGENT BILL SMITH,  AND HAS HIGHEST SECURITY CLEARANCE.": RETURN 
  166. 8090  IF FW%(1) = 14  THEN  PRINT "THEY APPEAR TO BE THE FRAGMENTS OF A    BUTCHER'S KNIFE.": RETURN 
  167. 8100  IF FW%(1) = 11  THEN 8200
  168. 8110  IF FW%(1) = 13  THEN 8300
  169. 8190  PRINT "NOTHING INTERESTING.": RETURN 
  170. 8200  PRINT "TITLE: HOW TO MAKE THE MOST OF COMPUTER        NETWORKS"
  171. 8210  PRINT : PRINT "YOU CAN ACCESS THE GOVERNMENT'S PUBLIC  INFORMATION DATA FILES THROUGH ANY      MODEM-EQUIPPED COMPUTER.  TO DO THIS    SIMPLY TYPE:"
  172. 8220  PRINT "  PR#3"
  173. 8230  PRINT "THEN, YOU SELECT THE GOVERNMENT NETWORK BY TYPING:": PRINT "  GOVT"
  174. 8240  PRINT "NOW YOU ARE ASKED THE NAME OF THE FILE  YOU WANT.  FILES YOU HAVE ACCESS TO"
  175. 8250  PRINT "INCLUDE 'POP', WHICH CONTAINS THE       CURRENT POPULATION OF THE U.S.A.        HAVE FUN!"
  176. 8260  RETURN 
  177. 8300  PRINT "          T O P    S E C R E T"
  178. 8310  PRINT "TO: WORKERS ON PROJECT CHRONOS"
  179. 8320  PRINT : PRINT "THE CURRENT COMBINATION TO THE DOOR OF  ROOM ";RM" IS POSTED ON THE GOVERNMENT": PRINT "COMPUTER NETWORK IN THE FILE TITLED     'CHRONOS'.  THE PASSWORD TO THE FILE    IS '";PW$(PW);"'."
  180. 8330  RETURN 
  181. 8490  RETURN 
  182. 8500  REM  TRIAL/JAIL
  183. 8510  PRINT "* A POLICE ROBOT ARRIVES. *"
  184. 8515  PRINT 
  185. 8520  PRINT "POLICE: YOU ARE UNDER ARREST. YOU HAVE A RIGHT TO REFRAIN FROM INPUTTING         ANYTHING; ANYTHING YOU INPUT MAY BE     HELD AGAINST YOU IN COURT."
  186. 8540  PRINT : PRINT "* YOU ARE TAKEN TO A COURTROOM.      *  * THE JUDGE AND JURY ARE ALL ROBOTS. *"
  187. 8550  PRINT 
  188. 8560  PRINT : PRINT "JUDGE: YOU ARE CHARGED WITH ";
  189. 8580  IF CH = 1  THEN  PRINT "ASSAULT OF": PRINT " A ROBOT. ";
  190. 8590  IF CH < >1  THEN  PRINT "THEFT OF": PRINT " SERVICES. ";
  191. 8600  PRINT "HOW DO YOU PLEAD?"
  192. 8605  PRINT 
  193. 8610  INPUT "DEFENDANT: ";I$
  194. 8615  PRINT 
  195. 8620  IF  LEN(I$) > = 6  AND  LEFT$(I$,6) = "GUILTY"  THEN 8900
  196. 8630  PRINT "JUDGE: THE DISTRICT ATTORNEY WILL NOW    PRESENT HIS CASE."
  197. 8635  PRINT 
  198. 8640  PRINT "* THE D.A. IS ALSO A ROBOT. *"
  199. 8645  PRINT 
  200. 8650  PRINT "D.A.: I WILL NOW CALL UPON THE ";
  201. 8660  IF R%(L) = 1  THEN  PRINT "CLERK "
  202. 8665  IF R%(L) < >1  THEN  PRINT "GUARD "
  203. 8670  PRINT " ROBOT, SERIAL #" INT( RND(1) *999999)" TO TESTIFY."
  204. 8672  PRINT 
  205. 8677  IF CH < >1  THEN 8700
  206. 8680  PRINT "ROBOT: THIS MAN ASSAULTED ME WITH A": IF IL%(9) = 0  THEN  PRINT " RAY GUN ";
  207. 8685  IF IL%(9) < >0  THEN  PRINT " KNIFE ";
  208. 8690  PRINT "ONLY " INT( RND(1) *59)" MINUTES, " RND(1) *59: PRINT " SECONDS AGO."
  209. 8692  PRINT 
  210. 8695  PRINT "D.A.: I REST MY CASE."
  211. 8696  PRINT 
  212. 8697  GOTO 8800
  213. 8700  REM  THEFT OF SERVICES
  214. 8710  PRINT "ROBOT: THIS MAN HAD A MEAL AT THE        RESTAURANT IN WHICH I WORK, AND WOULD   NOT PAY."
  215. 8715  PRINT 
  216. 8720  PRINT "D.A.: WHEN DID THIS HAPPEN?"
  217. 8725  PRINT 
  218. 8730  PRINT "ROBOT: JUST "; INT( RND(1) *59)" MINUTES, " RND(1) *59: PRINT " SECONDS AGO."
  219. 8735  PRINT 
  220. 8740  PRINT "D.A.: I REST MY CASE."
  221. 8745  PRINT 
  222. 8800  REM  YOUR REPLY
  223. 8810  PRINT "JUDGE: WHAT DOES THE DEFENDANT HAVE TO   SAY FOR HIMSELF?"
  224. 8815  PRINT 
  225. 8820  INPUT "DEFENDANT: ";I$
  226. 8822  PRINT 
  227. 8825  PRINT "JUDGE: THE JURY WILL NOW REACH A         VERDICT.": FOR A = 1 TO 1500: NEXT A
  228. 8827  PRINT 
  229. 8830  PRINT "JURY: THE WORD OF A ROBOT IS MORE        RELIABLE THAN THAT OF A MERE HUMAN.     THEREFORE, I FIND THE DEFENDANT GUILTY  AS CHARGED."
  230. 8840  PRINT 
  231. 8900  REM  SENTENCING
  232. 8905 SE = 2
  233. 8910  IF CH = 1  THEN  PRINT "JUDGE: YOU ARE HEREBY SENTENCED TO DEATH BY ELECTROCUTION.": PRINT : PRINT "YOU LOSE.": PRINT "STOP AFTER ";T;" TURNS.": SPEED= 255: END 
  234. 8920  PRINT "JUDGE: YOU ARE HEREBY SENTENCED TO": PRINT " "SE" YEARS IN PRISON. BAILIFF, PLEASE": PRINT " REMOVE THE PRISONER... NEXT CASE!"
  235. 8930  PRINT :L = 28
  236. 8940  FOR A = 1 TO NI: IF IL%(A) = 0  THEN IL%(A) = 29
  237. 8942 M =  - ABS(M)
  238. 8945  NEXT A
  239. 8950 XX = 1: RETURN 
  240. 9000  REM  SHOOT
  241. 9010  IF IL%(9) < >0  THEN  PRINT "WITH WHAT?": RETURN 
  242. 9020  IF R%(L) = 0  THEN  PRINT "NOTHING TO SHOOT AT.": RETURN 
  243. 9030  IF R%(L) < >3  THEN  PRINT "THE ROBOT'S FORCE FIELD REPELS THE      RAY.":CH = 1: GOTO 8500
  244. 9040  PRINT "THE DEFECT WHICH CAUSED THE ROBOT TO    MALFUNCTION ALSO AFFECTED ITS NORMALLY"
  245. 9050  PRINT "INVULNERABLE FORCE-FIELD.  YOUR SHOT    DESTROYS IT."
  246. 9060 R%(L) = 0
  247. 9070  RETURN 
  248. 9500  REM  BUY
  249. 9501  IF FW%(1) <1  OR FW%(1) >NI  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  250. 9503  IF IL%(FW%(1)) = 0  THEN  PRINT "YOU ARE ALREADY CARRYING IT!": RETURN 
  251. 9505  IF IL%(FW%(1)) < >L  THEN  PRINT "NO SUCH THING HERE.": RETURN 
  252. 9510  IF PR(FW%(1)) = 0  THEN  PRINT "THERE IS NO PRICE ON IT.": RETURN 
  253. 9520 P = PR(FW%(1))
  254. 9530  IF P >M  THEN  PRINT "YOU DON'T HAVE ENOUGH MONEY!": RETURN 
  255. 9540 M = M -P
  256. 9550 PR(FW%(1)) = 0
  257. 9560  GOTO 3000
  258. 10000  REM  COMPUTER
  259. 10002  IF IL%(4) < >L  THEN  PRINT "NOTHING TO TURN ON.": RETURN 
  260. 10005  PRINT "ROBOT: WHEN YOU ARE FINISHED, TYPE       'OFF' TO SHUT IT OFF.": PRINT : INPUT "HIT RETURN TO TURN APPLE X ON. ";I$
  261. 10007  SPEED= 255
  262. 10010  HOME : PRINT "           A P P L E   X": PRINT 
  263. 10020  PRINT 2 ^25 -2000;" BYTES FREE"
  264. 10030  PRINT : INPUT ">";I$
  265. 10040  IF I$ = "PR#3"  THEN 10100
  266. 10045  IF I$ = "OFF"  THEN XX = 1: SPEED= 128: RETURN 
  267. 10050 I =  INT( RND(1) *5) +1
  268. 10055  ON I GOSUB 10060,10065,10070,10075,10080: GOTO 10030
  269. 10060  PRINT "SYNTAX ERROR<CTRL-G>": RETURN 
  270. 10065  PRINT "IMPROPER DELIMITER ERROR<CTRL-G>": RETURN 
  271. 10070  PRINT "UNBALANCED COORDINATE ERROR<CTRL-G>": RETURN 
  272. 10075  PRINT "UNFORMATTED REFERENCE ERROR<CTRL-G>": RETURN 
  273. 10080  PRINT "UNINDEXABLE ADDRESS ERROR<CTRL-G>": RETURN 
  274. 10100  REM  MODEM
  275. 10110  PRINT : PRINT "YOU ARE NOW IN NETWORK MODE."
  276. 10120  PRINT : INPUT ")";I$
  277. 10125  IF I$ = "OFF"  THEN XX = 1: SPEED= 128: RETURN 
  278. 10130  IF I$ < >"GOVT"  THEN  PRINT "INPROPER DATA BANK REFERENCE<CTRL-G>": GOTO 10120
  279. 10140  INPUT "FILE NAME: ";I$
  280. 10150  IF I$ = "POP"  THEN  PRINT "CURRENT POPULATION OF USA ACCORDING     TO CENSUS BUREAU AS OF 7/6/2121:        EXACTLY 0 PERSONS,                      23,241,203 ROBOTS.": GOTO 10120
  281. 10160  IF I$ = "CHRONOS"  THEN 10200
  282. 10170  PRINT "NO SUCH FILE<CTRL-G>": GOTO 10120
  283. 10200  REM  CHRONOS
  284. 10210  INPUT "PASSWORD: ";I$
  285. 10220  IF I$ < >PW$(PW)  THEN  PRINT "IMPROPER PASSWORD": GOTO 10120
  286. 10230  PRINT "THE COMBINATION IS ";CM%
  287. 10240  GOTO 10120
  288. 11000  REM  RESTAURANT
  289. 11010  PRINT "ROBOT: HERE IS THE MENU:"
  290. 11020  PRINT "  (1) MARSBURGER"
  291. 11025  PRINT "      $120"
  292. 11030  PRINT "  (2) GREEN GOOP (SPECIAL OF THE WEEK!)"
  293. 11035  PRINT "      $140"
  294. 11040  PRINT "  (3) CAVIAR AND CHAMPAGNE"
  295. 11045  PRINT "      $350"
  296. 11047  PRINT "(HIT RETURN IF YOU DO NOT WANT           TO ORDER.)"
  297. 11050  PRINT : INPUT "YOUR ORDER: ";I$
  298. 11060  IF I$ = ""  THEN  RETURN 
  299. 11070  IF  VAL(I$) <1  OR  VAL(I$) >3  THEN 11050
  300. 11080  PRINT : PRINT "YOU ARE SERVED."
  301. 11090  PRINT "MMM. IT TASTES GOOD."
  302. 11095 E = T
  303. 11100  PRINT : PRINT "ROBOT: YOUR CHECK, SIR."
  304. 11120  PRINT : PRINT "YOU DO NOT HAVE ENOUGH MONEY!"
  305. 11130 CH = 0: GOTO 8500
  306. 12000  REM  SUBWAY
  307. 12005 L = LV%(L,6)
  308. 12010  PRINT "YOU ENTER AT THE ";LD$(L,1): PRINT "STATION."
  309. 12015  PRINT 
  310. 12020  IF LV%(L,1) < >0  AND LV%(L,2) < >0  THEN  PRINT "WHICH TRAIN: NORTHBOUND OR SOUTHBOUND?": INPUT "";I$:I = 2: IF  LEFT$(I$,1) = "N"  THEN I = 1
  311. 12030  IF LV%(L,1) = 0  THEN I = 2
  312. 12040  IF LV%(L,2) = 0  THEN I = 1
  313. 12050 L = LV%(L,I)
  314. 12060  PRINT "NEXT STATION: ";LD$(L,1)
  315. 12065  IF LV%(L,I) = 0  THEN  PRINT "END OF THE LINE.":L = LV%(L,8):XX = 1: RETURN 
  316. 12070  PRINT 
  317. 12080  INPUT "DO YOU WANT TO GET OFF HERE? ";I$: IF  LEFT$(I$,1) = "Y"  THEN L = LV%(L,8):XX = 1: RETURN 
  318. 12090  PRINT : GOTO 12050
  319. 13000  REM  CALL ROBOT
  320. 13002  IF R%(L) = 0  THEN  PRINT "NOBODY TO CALL.": RETURN 
  321. 13003  IF R%(L) < >1  THEN 13200
  322. 13010  IF L = 6  THEN 11000
  323. 13020  IF L = 34  THEN 13300
  324. 13030  IF L = 36  THEN 13400
  325. 13040  IF L = 3  THEN  PRINT "ROBOT: WOULD YOU LIKE TO TRY OUT THE     APPLE X?": INPUT "";I$: IF  LEFT$(I$,1) = "Y"  THEN 10000
  326. 13045  IF L = 3  THEN  RETURN 
  327. 13050  PRINT "ROBOT: CAN I HELP YOU?"
  328. 13060  INPUT " ";I$
  329. 13065  IF I$ = ""  THEN 13060
  330. 13070  GOSUB 520
  331. 13080  IF FW%(0) = 10  THEN  GOSUB 9500: RETURN 
  332. 13085  IF FW%(1) = 4  AND L = 3  THEN 10000
  333. 13090  PRINT "ROBOT: I AM NOT PROGRAMMED TO ANSWER     QUERIES OF THIS TYPE."
  334. 13190  RETURN 
  335. 13200  REM  GUARD AND BERZERK ROBOTS
  336. 13210  IF R%(L) = 3  THEN  PRINT "THE ROBOT KILLS YOU WHILE YOU ARE       ATTEMPTING TO COMMUNICATE WITH IT!": PRINT : PRINT "STOP AFTER ";T;" TURNS.": END 
  337. 13220  PRINT "ROBOT: YES?"
  338. 13230  INPUT " ";I$
  339. 13240  PRINT "ROBOT: TELL THAT TO THE JUDGE!"
  340. 13250  RETURN 
  341. 13300  REM  UNIVERSITY
  342. 13310  PRINT "ROBOT: WHAT ROOM NUMBER DO YOU NEED?": INPUT "";I$
  343. 13320  IF  VAL(I$) < >RM  THEN  PRINT "ROBOT: SORRY, THAT ROOM IS NOT OPEN.": RETURN 
  344. 13330  PRINT : PRINT "THE WALL SLIDES OPEN, AND YOU ARE       BRISKLY CARRIED ON A PLATFORM FLOATING  INCHES ABOVE THE FLOOR, THROUGH SEVERAL HALLWAYS.  YOU COME TO A STOP."
  345. 13340 L = 36:XX = 1: RETURN 
  346. 13400  REM  HALL
  347. 13410  PRINT "ROBOT: DO YOU WANT TO GO BACK TO THE     LOBBY?": INPUT "";I$: IF  LEFT$(I$,1) = "Y"  THEN L = 34:XX = 1: RETURN 
  348. 13420  RETURN 
  349. 13500  REM  PLAY GAME
  350. 13510  PRINT : PRINT "COST: $2.50"
  351. 13520  IF M <2.5  THEN  PRINT "YOU CAN'T AFFORD IT.": RETURN 
  352. 13525  SPEED= 255
  353. 13530 M = M -2.5
  354. 13540  GR : HOME 
  355. 13550 GX = 20:GY = 20:GT = 200:GS = 0
  356. 13555 GH = 0
  357. 13560  PRINT "**** SUPER STELLAR ALIEN KAPOW! ****"
  358. 13565  GOSUB 13570: GOTO 13600
  359. 13570  PRINT "SCORE="GS"   " TAB( 20)"TIME LEFT: "GT"    "
  360. 13580  PRINT "X COORD="GX"   " TAB( 20)"Y COORD="GY"  "
  361. 13590  PRINT "Q TOLERANCE=" INT( RND(1) *1000)"   " TAB( 20)"X-Y DECLENSION=" INT( RND(1) *100)"  ";
  362. 13595  RETURN 
  363. 13600  REM 
  364. 13610  COLOR= 15: PLOT GX,GY
  365. 13620  IF  RND(0) >.75  THEN  COLOR=  INT( RND(1) *15): PLOT  INT( RND(1) *40), INT( RND(1) *40): PRINT "<CTRL-G>";
  366. 13630 I =  PEEK( -16384): POKE  -16368,0
  367. 13635 GA = GX:GB = GY
  368. 13637 GF = 0
  369. 13640  IF I = 136  THEN GA = GX -1: IF GA <0  THEN GA = 0
  370. 13650  IF I = 149  THEN GA = GX +1: IF GA >39  THEN GA = 39
  371. 13660  IF I = 141  THEN GB = GY -1: IF GB <0  THEN GB = 0
  372. 13670  IF I = 175  THEN GB = GY +1: IF GB >39  THEN GB = 39
  373. 13675  IF I = 160  THEN GF = 1
  374. 13680  COLOR= 0: PLOT GX,GY
  375. 13690  IF  SCRN( GA,GB) < >0  THEN  PRINT "<CTRL-G><CTRL-G><CTRL-G>";:GS = GS +10 * SCRN( GA,GB)
  376. 13692  IF GF = 0  THEN 13700
  377. 13693  FOR A = 0 TO 39: IF  SCRN( GA,A) < >0  AND  SCRN( GA,A) < >15  THEN GS = GS +5 * SCRN( GA,A): PRINT "<CTRL-G><CTRL-G>";
  378. 13696  IF  SCRN( A,GB) < >0  AND  SCRN( A,GB) < >15  THEN GS = GS +5 * SCRN( A,GB): PRINT "<CTRL-G><CTRL-G>";
  379. 13698  NEXT A: COLOR= 15: HLIN 0,39 AT GB: VLIN 0,39 AT GA: COLOR= 0: HLIN 0,39 AT GB: VLIN 0,39 AT GA
  380. 13700  COLOR= 15: PLOT GA,GB:GX = GA:GY = GB
  381. 13710  VTAB 22: HTAB 1: GOSUB 13570
  382. 13720 GT = GT -1: IF GT >0  THEN 13600
  383. 13730  IF GS -GH >1000  THEN  PRINT "<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>";:GH = GS:GT = 75: GOTO 13600
  384. 13800  TEXT : HOME : VTAB 12: HTAB 6: PRINT "G A M E   O V E R": PRINT : PRINT  TAB( 6)"FINAL SCORE: "GS: PRINT 
  385. 13805  SPEED= 128
  386. 13810 XX = 0: GOSUB 1000: RETURN 
  387. 14000  REM  TIME MACHINE
  388. 14010  PRINT "YOU ARE IN THE TIME MACHINE!"
  389. 14020  PRINT "NOW SET THE CONTROLS."
  390. 14030  INPUT "YEAR: ";Y
  391. 14040  INPUT "MONTH: ";I$: INPUT "DAY: ";I$: INPUT "HOUR: ";I$: INPUT "MINUTE: ";I$: INPUT "SECOND: ";I$
  392. 14050  PRINT : PRINT "THE MACHINE WHIRRS..."
  393. 14060  FOR A = 1 TO 1000: NEXT A
  394. 14070  PRINT "YOU HAVE ARRIVED!"
  395. 14080  IF Y > = 1970  AND Y <2000  THEN  PRINT "BACK IN THE 20TH CENTURY AT LAST!       YOU WIN!"
  396. 14085  IF Y > = 1970  AND Y <2000  THEN  PRINT "  FOR EXTRA CREDIT YOU CAN TRY TO FIGUREOUT THE RULES TO THE ARCADE GAME, IF YOUHAVEN'T ALREADY.  IT IS TOTALLY": PRINT "IRRELEVANT TO THE ADVENTURE, BUT I THREWIT IN FOR THE HECK OF IT."
  397. 14090  IF Y > = 2000  THEN  PRINT "WHY DID YOU GO TO THE FUTURE AGAIN?     I DIDN'T PROGRAM ANY ADVENTURE GAME FOR THAT CENTURY, AND THE TIME MACHINE IS   OUT OF POWER. YOU'RE ON YOUR OWN."
  398. 14100  IF Y <1970  AND Y > = 1900  THEN  PRINT "WELL, AT LEAST YOU MADE IT TO THE 20TH  CENTURY, BUT YOU'LL HAVE TO WAIT AROUND A WHILE FOR APPLE COMPUTERS TO COME.": IF Y <1939  THEN  PRINT "PS: BUY ACTION COMICS #1 FOR 10 CENTS   WHEN IT COMES OUT."
  399. 14110  IF Y <1900  THEN  PRINT "YOU END UP IN THE YEAR ";Y;". I DIDN'T": PRINT "PROGRAM ANY ADVENTURE GAME FOR THAT     CENTURY, AND THE TIME MACHINE IS OUT    OF POWER. YOU'RE ON YOUR OWN."
  400. 14120  PRINT "STOP AFTER "T" TURNS.": SPEED= 255: END 
  401. 14500  REM  EAT
  402. 14502  IF FW%(1) = 0  AND L = 6  THEN 11000
  403. 14510  IF FW%(1) <1  OR FW%(1) >NI  THEN  PRINT "EAT WHAT?": RETURN 
  404. 14520  IF IL%(FW%(1)) < >0  THEN  PRINT "EAT WHAT?": RETURN 
  405. 14530  IF IW(FW%(1)) >2  THEN  PRINT "DON'T BE RIDICULOUS.": RETURN 
  406. 14540  IF FW%(1) = 3  THEN  PRINT "MMM. THAT WAS GOOD.":E = T: GOTO 14565
  407. 14542  SPEED= 30
  408. 14545  PRINT "CHOMP CHOMP CHOMP"
  409. 14547  SPEED= SP
  410. 14550  PRINT "IT COULD HAVE USED A LITTLE SALT."
  411. 14560  IF T -E >150  THEN  PRINT "NOT VERY NUTRITIOUS. I'M STILL HUNGRY."
  412. 14565 IL%(FW%(1)) =  -1
  413. 14567  IF FW%(1) = 10  THEN M = 0
  414. 14570  RETURN 
  415. 15000  REM  BREAK OUT OF JAIL
  416. 15010  IF L < >28  THEN  PRINT "WHAT?": RETURN 
  417. 15020  PRINT "THE RUSTY, WEAKENED BARS GIVE WAY AND   THERE IS AN OPENING OUT."
  418. 15030 LV%(28,8) = 27:J = 1
  419. 15040  RETURN 
  420. 15500  REM  ATTACK
  421. 15510  IF IL%(9) = 0  THEN 9000
  422. 15515  IF R%(L) = 0  THEN  PRINT "NOTHING TO ATTACK.": RETURN 
  423. 15520  IF IL%(1) < >0  THEN  PRINT "YOU HAVE NO HOPE OF FIGHTING A TOUGH    METAL ROBOT WITH YOUR BARE HANDS.": RETURN 
  424. 15530  PRINT "THE KNIFE SHATTERS AGAINST THE ROBOT'S  TOUGH SIDE."
  425. 15535 IL%(1) =  -1
  426. 15537 IL%(14) = L
  427. 15538  IF R%(L) = 3  THEN  PRINT "THE ROBOT KILLS YOU.": PRINT "STOP AFTER "T" TURNS.": SPEED= 255: END 
  428. 15540 CH = 1: GOTO 8500
  429. 16000  REM  OPEN
  430. 16010  PRINT "ALL THE DOORS OPEN AND CLOSE            AUTOMATICALLY, SO THERE IS NO NEED TO   OPEN THEM OR CLOSE THEM."
  431. 16020  RETURN 
  432. 16500  REM  HELP
  433. 16510  HOME : PRINT 
  434. 16520  PRINT "SOME AVAILABLE COMMANDS: ": PRINT 
  435. 16530  PRINT " INV": PRINT " GET (OBJECT)": PRINT " BUY (OBJECT)": PRINT " DROP (OBJECT)"
  436. 16540  PRINT " EXAMINE (OBJECT)": PRINT " CALL ROBOT": PRINT " ATTACK ROBOT"
  437. 16545  PRINT " SHOOT ROBOT": PRINT " LOOK"
  438. 16550  PRINT : RETURN 
  439. 17990  RETURN 
  440. 18000  REM  OPENING TITLES
  441. 18010  TEXT : HOME 
  442. 18020  VTAB 4: HTAB 3
  443. 18030  PRINT "**** PLANET OF THE ROBOTS ****"
  444. 18040  PRINT : HTAB 3
  445. 18050  PRINT "BY DANIEL TOBIAS      NOV. 1981"
  446. 18060  PRINT 
  447. 18070  HTAB 3: INPUT "INSTRUCTIONS? (Y/N) ";I$: IF  LEFT$(I$,1) = "N"  THEN  HOME : PRINT : RETURN 
  448. 18500  REM  INSTRUCTIONS
  449. 18510  HOME : PRINT 
  450. 18520  PRINT "A TIME WARP HAS SUDDENLY TRANSPORTED": PRINT 
  451. 18530  PRINT "YOU INTO THE FUTURE, WHEN A WAR USING"
  452. 18540  PRINT 
  453. 18550  PRINT "NEUTRON BOMBS AND BACTERIOLOGICAL": PRINT 
  454. 18560  PRINT "WARFARE HAS COMPLETELY WIPED OUT THE": PRINT : PRINT "HUMAN RACE.  HOWEVER, THE COMPUTERS"
  455. 18570  PRINT : PRINT "AND ROBOTS DON'T KNOW THIS, AND KEEP": PRINT 
  456. 18580  PRINT "GOING ABOUT THEIR BUSINESS AS IF NOTHING": PRINT "HAS HAPPENED."
  457. 18585  PRINT : INPUT "*** HIT RETURN TO CONTINUE ***";I$: HOME 
  458. 18590  PRINT : PRINT : PRINT "YOU EXPLORE THE WORLD YOU ARE THRUST": PRINT : PRINT "INTO USING SIMPLE SENTENCES, IN THE"
  459. 18600  PRINT : PRINT "STANDARD ADVENTURE-GAME FASHION, SUCH"
  460. 18610  PRINT : PRINT "AS 'ATTACK ROBOT' OR 'EXAMINE COIN'.": PRINT 
  461. 18620  PRINT "IF A ROBOT IS IN THE ROOM, YOU MAY ": PRINT : PRINT "ATTEMPT TO TALK TO IT BY"
  462. 18630  PRINT : PRINT "TYPING 'CALL ROBOT', BUT POSITIVE": PRINT : PRINT "RESULTS ARE NOT GUARANTEED!"
  463. 18635  PRINT : INPUT "*** HIT RETURN TO CONTINUE ***";I$: HOME 
  464. 18640  PRINT : PRINT "'GO NORTH' MAY BE ABBREVIATED 'N', AND": PRINT : PRINT "THE SAME CAN BE DONE WITH THE OTHER"
  465. 18650  PRINT : PRINT "COMPASS DIRECTIONS."
  466. 18660  PRINT : PRINT "THE OBJECT IS TO GET BACK TO THE 20TH": PRINT : PRINT "CENTURY.  GOOD LUCK!"
  467. 18665  PRINT : PRINT "SOME UTILITY COMMANDS:": PRINT "  QUIT - EXITS GAME"
  468. 18666  PRINT "  SAVE - SAVES GAME TO DISK: YOU WILL BE         ASKED TO SPECIFY A GAME NUMBER.         THIS CAN BE ANY POSITIVE INTE-          GER, AND THE GAME WILL BE SAVED";
  469. 18667  PRINT "         IN THE RECORD OF THAT NUMBER            OF RANDOM-ACCESS DISK FILE              'GAME.PLANET.OF.THE.ROBOTS'."
  470. 18670  PRINT : INPUT "*** HIT RETURN TO BEGIN ***";I$: HOME : PRINT : RETURN 
  471. 19000  REM  INITIALIZE 
  472. 19002  PRINT "PLEASE WAIT. INITIALIZING DATA."
  473. 19005  FOR A = 1 TO 8: READ DN$(A): NEXT A
  474. 19020 A = 1
  475. 19025  FOR B = 0 TO 1: READ LD$(A,B): NEXT B: IF LD$(A,0) < >""  THEN A = A +1: GOTO 19025
  476. 19027 NL = A -1
  477. 19030  FOR A = 1 TO NL: FOR B = 1 TO 8: READ LV%(A,B): NEXT B: READ R%(A): NEXT A
  478. 19040  FOR A = 1 TO NL:L%(A) = 0: NEXT A
  479. 19050 A = 1
  480. 19060  READ ID$(A),IL%(A),IW(A),PR(A): IF IL%(A) < > -999  THEN A = A +1: GOTO 19060
  481. 19065 NI = A -1
  482. 19067  FOR A = 1 TO 10: READ PW$(A): NEXT A
  483. 19070 A = 1
  484. 19075  READ WD$(A),W%(A,0),W%(A,1): IF WD$(A) < >""  THEN A = A +1: GOTO 19075
  485. 19080 NW = A -1
  486. 19085 L = 1:T = 1
  487. 19087 W = 0:M =  -119
  488. 19088 E = 0:J = 0:R = 0
  489. 19090  HOME : PRINT : INPUT "LOAD GAME FROM DISK? (Y/N) ";I$
  490. 19092 DUMMY =  RND( - PEEK(79) *256 - PEEK(78)): REM RANDOM SEED
  491. 19093 PW =  INT( RND(1) *10) +1
  492. 19096 CM% =  INT( RND(1) *9999):RM =  INT( RND(1) *900) +100
  493. 19100  IF  LEFT$(I$,1) = "Y"  THEN  GOSUB 6500
  494. 19120  RETURN 
  495. 20000  REM  DATA
  496. 20005  DATA  "N ","S ","E ","W ","U ","D ","IN ","OUT"
  497. 20010  REM  #PLACES
  498. 20030  REM  PLACE DESC,SHORT DESC
  499. 20040  DATA  "YOU ARE IN THE PARKING LOT OF A SHOPPINGMALL. A ROAD IS TO THE EAST.","YOU'RE IN PARKING LOT TO MALL"
  500. 20050  DATA  "YOU ARE IN THE SHOPPING MALL. THERE IS  A COMPUTER STORE NEXT TO YOU.","YOU'RE IN MALL AT COMPUTER STORE."
  501. 20060  DATA  "YOU ARE IN THE COMPUTER STORE.","YOU'RE IN COMPUTER STORE."
  502. 20070  DATA  "TO THE WEST IS A BACK-ISSUE COMIC BOOK  STORE; TO THE EAST IS A RESTAURANT.","YOU'RE BY COMIC STORE AND RESTAURANT."
  503. 20080  DATA  "THIS IS A STORE CATERING TO COMIC BOOK  COLLECTORS (YEP, THEY STILL EXIST EVEN  IN THE FUTURE.)","YOU'RE IN COMIC STORE."
  504. 20085  REM  6:
  505. 20090  DATA  "YOU ARE IN A RESTAURANT.","YOU'RE IN RESTAURANT."
  506. 20100  DATA  "TO THE WEST IS AN ARCADE, AND TO THE    EAST A GROCERY STORE.","YOU'RE BY ARCADE AND GROCERY."
  507. 20110  DATA  "YOU ARE IN AN ARCADE.","YOU'RE IN ARCADE."
  508. 20120  DATA  "TO THE WEST IS A BUTCHER SHOP, AND TO   THE EAST IS A CLOTHING STORE.","YOU'RE BY BUTCHER AND CLOTHING STORE."
  509. 20130  DATA  "YOU ARE IN A BUTCHER SHOP.","YOU'RE IN BUTCHER SHOP."
  510. 20140  DATA  "YOU ARE IN A CLOTHING STORE.","YOU'RE IN CLOTHING STORE."
  511. 20150  DATA  "YOU ARE IN A GROCERY.","YOU'RE IN GROCERY."
  512. 20160  DATA "YOU ARE ON A N-S ROAD.  THERE IS A      SHOPPING MALL TO THE WEST.","YOU'RE ON ROAD BY MALL."
  513. 20170  DATA  "AFTER GOING ABOUT 100 FEET YOU FIND THATTHE ROAD IS BLOCKED BY FALLEN DEBRIS ANDYOU CAN'T GO ANY FURTHER.","YOU'RE AT DEAD END"
  514. 20180  DATA "YOU ARE NEXT TO AN INFORMATION BOOTH    MANNED BY A ROBOT.  THE ROAD CONTINUES  SOUTH.","YOU'RE BY INFO BOOTH."
  515. 20190  DATA  "YOU ARE IN A PHONE BOOTH. THE PHONE IS  OUT OF ORDER, AND THE CASH BOX HAS BURSTOPEN.","YOU'RE IN PHONE BOOTH."
  516. 20200  DATA  "I","I"
  517. 20210  DATA  "YOU ARE IN THE LIBRARY.","YOU'RE IN LIBRARY."
  518. 20220  DATA  "TO THE WEST IS A LIBRARY, AND THE CITY  HALL IS TO THE EAST.","YOU'RE BY LIBRARY AND CITY HALL."
  519. 20230  DATA  "YOU'RE IN THE LOBBY OF THE CITY HALL.   THERE IS A STAIRWAY HERE.","YOU'RE IN CITY HALL LOBBY."
  520. 20240  DATA  "THE ROAD ENDS HERE. THERE IS A STAIRWAY LEADING DOWN TO A SUBWAY STATION.","YOU'RE BY SUBWAY STATION."
  521. 20245  DATA  "S","CITY HALL"
  522. 20250  DATA  "YOU ARE IN A HALLWAY LEADING TOWARDS    OFFICES TO THE EAST.","YOU'RE IN HALLWAY."
  523. 20260  DATA  "THERE IS AN OFFICE TO THE NORTH AND     ANOTHER TO THE SOUTH.","YOU'RE BETWEEN TWO OFFICES."
  524. 20270  DATA  "YOU ARE IN AN OFFICE.","YOU'RE IN OFFICE"
  525. 20280  DATA  "YOU ARE IN AN OFFICE.","YOU'RE IN OFFICE"
  526. 20290  DATA  "YOU ARE IN A HALLWAY IN THE JAIL.  A    CELL IS TO THE SOUTH AND A CLOSET TO THENORTH.  A STAIRWAY LEADS UP.","YOU'RE IN JAIL HALLWAY."
  527. 20300  DATA  "YOU ARE IN A JAIL CELL.","YOU'RE IN JAIL CELL."
  528. 20310  DATA  "YOU ARE IN A CLOSET.","YOU'RE IN A CLOSET."
  529. 20320  DATA  "S","MARKET STREET"
  530. 20330  DATA  "S","METRO UNIVERSITY"
  531. 20340  DATA  "S","ENDSVILLE"
  532. 20350  DATA  "YOU ARE ON A STREET WHICH IS BLOCKED IN BOTH DIRECTIONS BY FALLEN DEBRIS.","YOU'RE ON BLOCKED STREET."
  533. 20360  DATA  "YOU ARE IN THE MAIN LOBBY OF THE METRO  UNIVERSITY BUILDING.  NO DOORS OF ANY   KIND ARE VISIBLE BESIDES THE ENTRANCE   TO THE SUBWAY.","YOU'RE IN UNIVERSITY LOBBY."
  534. 20370  DATA "YOU ARE ON A PLAIN WHERE A BOMB BLAST   HAS COMPLETELY DESTROYED THE TOWN.      THERE IS RUBBLE ALL AROUND.  THE PLAIN  STRETCHES INTO THE MIST.","YOU'RE BY SUBWAY STOP."
  535. 20380  DATA "YOU ARE IN FRONT OF A DOOR.","YOU'RE IN FRONT OF DOOR."
  536. 20390  DATA  "YOU ARE IN THE LABORATORY FOR                    *** PROJECT CHRONOS ***        THE TOP SECRET PROJECT WHICH DID        RESEARCH INTO TIME TRAVEL.","YOU'RE IN LAB."
  537. 20400  DATA  "T","T"
  538. 20405  DATA  "YOU ARE ON PLAIN.","YOU ARE ON PLAIN."
  539. 20410  DATA "YOU ARE BY A PHONE BOOTH.","YOU'RE BY PHONE BOOTH."
  540. 20990  DATA  "",""
  541. 21000  REM  MOVEMENT, ROBOTS
  542. 21010  DATA  0,0,13,0,0,0,2,0,0
  543. 21020  DATA  7,4,0,0,0,0,3,1,0
  544. 21030  DATA  0,0,0,0,0,0,0,2,1
  545. 21040  DATA  2,0,6,5,0,0,0,0,0
  546. 21050  DATA  0,0,0,0,0,0,0,4,1
  547. 21055  REM  6:
  548. 21060  DATA  0,0,0,0,0,0,0,4,1
  549. 21070  DATA  9,2,12,8,0,0,0,0,0
  550. 21080  DATA  0,0,0,0,0,0,0,7,0
  551. 21090  DATA  0,7,11,10,0,0,0,0,0
  552. 21100  DATA  0,0,0,0,0,0,0,9,0
  553. 21110  DATA  0,0,0,0,0,0,0,9,1
  554. 21120  DATA  0,0,0,0,0,0,0,7,1
  555. 21130  DATA  14,15,0,1,0,0,0,0,0
  556. 21140  DATA  0,13,0,0,0,0,0,0,0
  557. 21150  DATA 13,19,0,0,0,0,17,0,0
  558. 21160  DATA 0,0,0,0,0,0,0,40,0
  559. 21170  DATA  0,0,0,0,0,0,0,15,1
  560. 21180  DATA  0,0,0,0,0,0,0,19,0
  561. 21190  DATA  15,21,20,18,0,0,0,0,0
  562. 21200  DATA  0,0,0,0,23,27,0,19,26
  563. 21210  DATA  19,0,0,0,0,22,0,0,3
  564. 21215  DATA  0,30,0,0,0,0,0,21,0
  565. 21220  DATA  0,0,24,0,0,20,0,0,23
  566. 21230  DATA  26,25,0,23,0,0,0,0,0
  567. 21240  DATA  0,0,0,0,0,0,0,24,3
  568. 21245  DATA  0,0,0,0,0,0,0,24,0
  569. 21250  DATA  29,28,0,0,20,0,0,0,25
  570. 21260  DATA  0,0,0,0,0,0,0,0,0
  571. 21270  DATA  0,0,0,0,0,0,0,27,0
  572. 21280  DATA  22,31,0,0,0,0,0,33,0
  573. 21290  DATA  30,32,0,0,0,0,0,34,0
  574. 21300  DATA  31,0,0,0,0,0,0,35,0
  575. 21310  DATA  0,0,0,0,0,30,0,0,0
  576. 21320  DATA  0,0,0,0,0,31,0,0,1
  577. 21330  DATA  39,39,39,39,0,32,0,0,0
  578. 21340  DATA  0,0,0,0,0,0,37,0,1
  579. 21350  DATA  0,0,0,0,0,0,38,36,0
  580. 21360  DATA  0,0,0,0,0,0,0,0,0
  581. 21370  DATA  39,39,39,39,0,0,0,0,0
  582. 21380  DATA  39,39,39,39,0,0,16,0,0
  583. 23000  REM   ITEMS
  584. 23030  DATA  BUTCHER'S KNIFE,10,15,0
  585. 23033  DATA  SCALE,10,140,0
  586. 23036  DATA  FOOD PILLS,12,1 ,10
  587. 23040  DATA  APPLE X COMPUTER,3,40,10000
  588. 23050  DATA VIDEO GAME MACHINE,8,-1,0
  589. 23060  DATA  SUIT OF CLOTHES,11,6,995
  590. 23070  DATA  TIE,11,.25,20
  591. 23090  DATA  COMIC,5,.3,6
  592. 23100  DATA  RAY GUN,14,3,0
  593. 23110  DATA  COINS,16,5,0
  594. 23120  DATA  BOOK,18,3,0
  595. 23130  DATA  I.D. CARD,29,.01,0
  596. 23140  DATA  LETTER,26,.05,0
  597. 23150  DATA  SHATTERED PIECES OF METAL,-1,15,0
  598. 23160  DATA  TIME MACHINE,37,2000,0
  599. 23990  DATA  "",-999,-999,-999
  600. 23995  DATA  SESAME,SNARK,QUARK,PEARTREE,MOONSHINE,SHOE,TURKEY,CHRISTMAS,HALLOWEEN,ROBOTWAR
  601. 24000  REM  WORDS
  602. 24030  DATA  N,1,101
  603. 24040  DATA  S,1,102
  604. 24050  DATA  E,1,103
  605. 24060  DATA  W,1,104
  606. 24070  DATA  U,1,105
  607. 24080  DATA  D,1,106
  608. 24090  DATA  IN,1,107
  609. 24100  DATA  OUT,1,108
  610. 24110  DATA  GET,2,-1
  611. 24140  DATA  GO,1,-1
  612. 24160  DATA  DROP,3,-1
  613. 24170  DATA  LOOK,4,-1
  614. 24180  DATA  INV,5,-1
  615. 24190  DATA  QUIT,99,-1
  616. 24200  DATA  SAVE,6,-1
  617. 24210  DATA  ROBOT,-1,200
  618. 24220  DATA  BUY,10,-1
  619. 24230  DATA  WEIGH,7,-1
  620. 24240  DATA  READ,8,-1
  621. 24250  DATA  EXAMINE,8,-1
  622. 24260  DATA  KNIFE,-1,1
  623. 24270  DATA  SCALE,-1,2
  624. 24280  DATA  PILLS,-1,3
  625. 24290  DATA  APPLE,-1,4
  626. 24300  DATA  COMPUTER,-1,4
  627. 24310  DATA  CALL,11,-1
  628. 24320  DATA  GAME,-1,5
  629. 24330  DATA  PLAY,12,-1
  630. 24340  DATA  SUIT,-1,6
  631. 24350  DATA  TIE,-1,7
  632. 24360  DATA  COMIC,-1,8
  633. 24370  DATA  EAT,13,-1
  634. 24380  DATA  BREAK,14,-1
  635. 24390  DATA  ESCAPE,14,-1
  636. 24400  DATA  GUN,-1,9
  637. 24410  DATA  COINS,-1,10
  638. 24420  DATA  MONEY,-1,10
  639. 24425  DATA  CASH,-1,10
  640. 24430  DATA  BOOK,-1,11
  641. 24440  DATA  SHOOT,9,-1
  642. 24450  DATA  ATTACK,15,-1
  643. 24460  DATA  I.D.,-1,12
  644. 24470  DATA  CARD,-1,12
  645. 24480  DATA  LETTER,-1,13
  646. 24490  DATA  PIECES,-1,14
  647. 24500  DATA  OPEN,16,-1
  648. 24505  DATA  CLOSE,16,-1
  649. 24510  DATA  HELP,17,-1
  650. 24515  DATA  ON,18,-1
  651. 24520  DATA  BARS,-1,200
  652. 24895  REM *****UNABBREVIATED:
  653. 24900  DATA  NORTH,1,101
  654. 24905  DATA  SOUTH,1,102
  655. 24910  DATA  EAST,1,103
  656. 24915  DATA  WEST,1,104
  657. 24920  DATA  UP,1,105
  658. 24925  DATA  DOWN,1,106
  659. 24930  DATA  INVENTORY,5,-1
  660. 24935  DATA  ENTER,1,107 
  661. 24940  DATA  EXIT,1,108
  662. 24990  DATA  "",-999,-999